@;@ RHP_name: The Burlap Bag
@;@ For: The LORD Cavern v1.7+
@;@ Written_by: Donald Tidmore
@;@ Email: ktidmore@bellsouth.net, donald.tidmore@usa.net
@;@ For testing April 2009 RHP Library unit codes work.  Created 07/01/03.
@;@  URL: http://camelot.legendarydragons.com/Scripts/
@;@
@;@@PROGRAM@ LORDCAVE
@;@@VERSION@ 1.80
@;@@NAME@ The Burlap Bag
@;@@SCRIPTVERSION 1.20

@SHOW@
    `%Event In The Forest`6
  `#---------------------------------------------------------
  `!You come across a burlap bag someone has dropped.
  `#  As you open it, you wonder what could be inside ...

@;@     -------- Testing of SKILL code, replacing FIGHTER:
`#    Setting Skill Class to Death Knight.
@CLASS@ =1

@IF@ FIGHTER   `%You remember how lovely `@Seth's `%song was earlier.
`6    You find an `!Orange Crystal `6lying inside ...

@IF@ FIGHTER @GOTO@ @#Orange
`#      It doesn't have any value, and you throw it away.
@GOTO@ @#NoValue1

@#Orange
`#      It is a `!magical amulet!  `0It grants you some `$Defense points.

`0  Debug: Current HITMAX value is:  `$@*@HITMAX@*@
@VARIABLE1@ =SKILL*2
@HITMAX@ +VARIABLE1
`0  Debug: SKILL is:  `$@*@SKILL@*@ Death Knight points.
`0  Debug: Revised value HITMAX is:  `$@*@HITMAX@*@
`0  Debug: SKILL*2 math: VARIABLE1 is:  `$@*@VARIABLE1@*@
@#NoValue1
`0 ----------------------------------------------------------------

@;@     -------- Testing of SKILLUSE code, replacing WEIRDEVENT:
@IF@ WEIRDEVENT   `%You think about the `!Angels in the Forest ...
@VARIABLE1@ =SKILLUSE*7
`0  Debug: value of SKILLUSE is:  `$@*@SKILLUSE@*@
`0  Debug: Value of VARIABLE1 is:  `$@*@VARIABLE1@*@
`0  You look a second time inside.  You find a `!Green Crystal,
`%    and look into it.

@IF@ WEIRDEVENT @GOTO@ @#White
`#  ... Nothing special happens, so you toss it away.
@GOTO@ @#NoValue3

@#White
`$  .., `$You feel the `$power of your `0`w `!increase.

@STRENGTH@ +VARIABLE1
`0  Debug: Revised STRENGTH is:  `$@*@STRENGTH@*@
`0  Debug: Value of VARIABLE1 is:  `$@*@VARIABLE1@*@

`0  You stash the crystal in a pocket.  `%Violet `0might like it.
@#NoValue3
`0 ----------------------------------------------------------------
@MORE@

@;@     ---------------- For Testing new SEENMASTER math coding:
@IF@ SEENMASTER   `%You remember that last fight with your `!Master.
@VARIABLE1@ =LEVEL*500
@VARIABLE2@ =SEENMASTER*VARIABLE1
`0  Debug: Value of VARIABLE1 is:  `$@*@VARIABLE1@*@
`0  Debug: Value of VARIABLE2 is:  `$@*@VARIABLE2@*@
`0  You look a third time into the bag.  You find a `!Yellow Crystal,
`%    raise it up to your eyes, and look into it.

@IF@ SEENMASTER @GOTO@ @#Crystal
`#  ... You throw it at a pesky crow, and move onward.
@GOTO@ @#NoValue4

@#Crystal
`#    It is a `!magical crystal!  `0It grants you some `$Experience.

@EXPERIENCE@ +VARIABLE2
`0  Debug: Value of EXPERIENCE is:  `$@*@EXPERIENCE@*@
`0  Debug: Value of VARIABLE2 is:  `$@*@VARIABLE2@*@
@#NoValue4

@END@

@;@ Created 07/01/03 for usage in RHP code testing.
@;@ -- Use of BARDSONG in Math command. - Grants 0 or 5 defense. CONFIRMED
@'@ -- Use of WEIRDEVENT code - Grants 0 or 7 Strength points.   CONFIRMED
@;@ -- Use of SEENMASTER code - Grants GOLD Points.              CONFIRMED
@;@ -- use of SEENDRAGON code - Grants some Forest Fights.       CONFIRMED
@;@ -- 07/02: SETHVIOLET code - Gold reward.                     CONFIRMED
@;@ 07/03: worked on fine-tuning the dialogue. v1.01

@;@ 02/20/2005: Moved SEENDRAGON, FAIRY, and SETHVIOLET code
@;@   to new GOBLIN.RHP script file. Changed version to 1.03.
@;@ 04/21/2007: updated email info in headers.
@;@ 06/27/2007: Added web-site URL line.  v1.05.

@;@ 06/07/2008: LORD color code tweaking

@;@ 04/18/2009: Worked on fixing errors with RHP math commands.
@;@ 04/18/09: Added SHOW command.

@;@ 04/20/09: added debug statements for script testing.
@;@   Notes: BARDSONG, WEIRDEVENT, & SEENMASTER are *NOT*
@;@   usable in math formulas now. Evaluate use of SKILL with
@;@   DEFENSE stat, use of SKILLUSE with STRENGTH stat.

@;@  09/04/09: Revised to use v1.20.
@;@  11/21/09: minor editing

@;@ 11/30/09: Changed VERSION to 1.80.  No SCRIPTVERSION change.