@;@ RHP_Name: Outlands Tavern Sample Program
@;@ For:  The Outlands Tavern v1.61+
@;@ Written_by:  Donald Tidmore
@;@   Fidonet Email:  1:/123/450
@;@   Email: ktidmore@bellsouth.net, donald.tidmore@usa.net
@;@   URL: http://camelot.legendarydragons.com/Scripts/
@;@
@;@ Feel free to use this in writing your own random happening.
@;@ Introduction stuff.
@;@@PROGRAM@ OUTLANDS
@;@@VERSION@ 1.80
@;@@NAME@ Outlands Tavern Sample Program
@;@@SCRIPTVERSION@ 1.40

@SHOW@
`0This is a sample of `@The Outlands Tavern's `!built
`0in programing language, `%`n`!.

@;@  Test usage of `n code for showing player's LORD name.
`!  Player `$`n `!is granted 25,000 Wisdom Points.
@EXPERIENCE@ +25000

`!  Player granted 25,000 Gold Coins.
@GOLD@ +25000
@MORE@

`!  Player granted 5,000 Gems.
@GEMS@ +5000

`!  Take away 10 Children from player.
@KIDS@ -10

`!  Grant player 20 children.
@KIDS@ +20
@MORE@

@;@  Test usage of `a and `w codes for showing Armour Name
@;@  and Weapon Name in scripts.  VERIFIED 12/09/2009.
`!Your weapon is `$`w.
`!Your armour is `$`a.

@;@  Test usage of FIGHTER, MAGIC, THIEF codes.  VERIFIED 12/09/2009
`%Determining which Skill Class you are studying:
@IF@ FIGHTER `0You are currently a `@Death Knight.
@IF@ MAGIC `0You are currently a `@Magician/Wizard.
@IF@ THIEF `0You are currently a `@Thief.
@MORE@

@;@  Test usage of HORSE, FAIRY codes.  VERIFIED 12/09/2009
@;@  @IF@ HORSE `0You have a Horse.
@;@  @IF@ FAIRY `0You have a Fairy.

@IFNOT@ HORSE `%You are on foot.  You are granted a Horse.
@IFNOT@ HORSE @HORSE@

@IFNOT@ FAIRY `%You don't have a Fairy.  You may have one now.
@IFNOT@ FAIRY @FAIRY@
@MORE@

@;@  Test usage of SPIRITS, and WEIRDEVENT codes:  VERIFIED 12/09/2009
@;@  @IF@ WEIRDEVENT `%Weird Event `0is activated.
@;@  @IFNOT@ WEIRDEVENT `%Weird Event `0is NOT activated.
@;@  @IFNOT@ WEIRDEVENT @WEIRDEVENT@

@;@  @IF@ SPIRITS `%High Spirits `0is activated.
@;@  @IFNOT@ SPIRITS `%High Spirits `0is NOT activated.

@IFNOT@ SPIRITS @SPIRITS@
@IFNOT@ WEIRDEVENT @WEIRDEVENT@

@;@  @IF@ SPIRITS `!You may now visit `$JENNIE `!in the Forest.
@;@  @IF@ WEIRDEVENT `!You can hear the Angels sing in the Forest.
@MORE@

@;@  `%  Determining if player needs to be healed:
@;@  `%  Decreasing player's Hitpoints by 50% now:
@;@  @HITPOINTS@ /2

@;@   Testing usage of HEAL code.  VERIFIED 12/09/09
@HEAL@

@;@   Testing usage of HEALED code:   VERIFIED 12/09/09
@IF@ HEALED  `0This Script Event has healed your injuries.
@IFNOT@ HEALED  `0You didn't have any injuries that needed healing.
@MORE@

@;@  `%  Determining if you are Male or Female:  VERIFIED 12/09/09
@;@  @IF@ FEMALE  `0You are a lady warrior.
@;@  @IF@ MALE    `0You are a male warrior.
@;@  @MORE@

@;@ Ask yes / no.
@;@   The `l code tells the script to not do a line feed.
`#Do you want to continue?`l
@YESNO@
@;@ Example of single character sections.

@##Y
@;@ If person chose 'Y', this is ran.

@#BUBUY
@CLEAR@
`$The Language!`0
`#-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
`!This new language lets people write their own random happenings!
`!You're a`# `c `!`l
@;@ Example of new @IF@ command
`!, `%`n`!!

@IF@ MARRIED @GOTO@ @#Married
`!You're not married.  Bummer.
@GOTO@ @#Continue

@#Married
`!You're married to `%`m`!!
@#Continue
`0
   `0(`$1`0) `!Send Test Mail!
   `0(`$2`0) `!Set gems = 15,000!
   `0(`$3`0) `!Show stats screen! {ACTIVE IN SORCERER ONLY}
   `0(`$4`0) `!Send Ansi File!    {ACTIVE IN SORCERER ONLY}
   `0(`$5`0) `!Divide GEMS by 5!
   `0(`$6`0) `!Multiply GEMS by 5!
   `0(`$7`0) `!Subtract GEMS by 5!
   `0(`$8`0) `!Add GEMS by 5!
   `0(`$9`0) `!Grant player a Fairy!
   `0(`$0,Q`0) `!Quit Script!


`0
@;@ Example of prompt!
@PROMPT@ 1234567890Q
@##1
@MAIL@
`0Test message from OTSAMPLE.RHP
@MAILEND@
@NEWS@
`# Outlands Tavern Sample Script Program`!!
@;@ End write with a line.
@NEWSEND@
@MORE@
@GOTO@ @#BUBUY

@##2
`0
Setting GEMS to 15,000
@NOSHOW@
@GEMS@ =15000
@SHOW@
@MORE@
@GOTO@ @#BUBUY

@##3
@STATS@
@MORE@
@GOTO@ @#BUBUY

@##4
@ANSISEND@ CAVES.ANS
@END@

@##5
@GEMS@ \5
@MORE@
@GOTO@ @#BUBUY
@END@

@##6
@GEMS@ *5
@MORE@
@GOTO@ @#BUBUY
@END@

@##7
@GEMS@ -5
@MORE@
@GOTO@ @#BUBUY
@END@

@##8
@GEMS@ +5
@MORE@
@GOTO@ @#BUBUY
@END@

@##9
`!Granting player a Fairy, if they don't have one already.
@IFNOT@ FAIRY @FAIRY@
@MORE@
@GOTO@ @#BUBUY
@END@

@##0
@##Q
@END@
`#Cool, Eh `%|n`#?
@MORE@
@END@

@;@ If person chose 'N', this is run.
@##N
`!Ok, your loss!
@MORE@
@END@

@;@ Revised script code 12/09/2009.