@;@RHP_Name: The Prehistoric Pool #2
@;@By Jason Brown
@;@Maintained by Donald Tidmore
@;@  Fidonet Email:  1:/123/450
@;@  Email: ktidmore@bellsouth.net, donald.tidmore@usa.net
@;@  URL: http://camelot.legendarydragons.com/Scripts/
@;@@PROGRAM@ GW13MAIN
@;@@VERSION@ 1.5
@;@@NAME@ The Prehistoric Pool #2
@;@@LIMIT@ 20
@;@@SCRIPTVERSION@ 1.20

@SHOW@

`%
`%Note:  This script requires usage of The Gateway v1.3+ Betas.
`%
`#You exit the `@Gateway Portal `#to find yourself in front of a
`#bubbling, Prehistoric Pool #2.

`#Should you approach it?  `l
@YESNO@
@##N
@GOTO@ @#EXIT

@##Y
@#MAINMENU
@CLEAR@
  `3The Prehistoric Pool #2
`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-`!=`3-
@;@                                                         v Max length (1 colorcode)
`%The pool bubbles and boils with its volcanic, prehistoric heat.
`%Who knows what could be in there...

  `@(`!L`@) `%Lean over the Pool
  `@(`!D`@) `%Drink from the Pool
  `@(`!J`@) `%Jump into the Pool
  `@(`!V`@) `%View your Stats
  `@(`!R`@) `%Run back to the `#Gateway Portal!
@PROMPT@ RLDJVQ
@##R
@##Q
@GOTO@ @#EXIT

@##V
@STATS@
@GOTO@ @#MAINMENU

@##L
@IF@ USER1=0 @GOTO@ @#BEGINL
`%You couldn't stand doing that again today.

@MORE@
@GOTO@ @#MAINMENU

@#BEGINL
@RANDOM@ 4
@##1
@##2
`3The pool just sits there and bubbles.  It also smells bad.

@MORE@
@GOTO@ @#ENDL

@##3
`%The pool spits in your face.  The hot water makes you jump
`%back and you drop `@all `%of your `%Gold `%in the pool!
@VARIABLE1@ =GOLD*1
    `#You just lost `$@*@GOLD@*@ `%Gold Coins!
@GOLD@ =0
@MORE@
@GOTO@ @#ENDL

@##4
`%You look in, and near your position, you see a diamond.  You
`%reach in and pull it out...

  `%Wow!  This could be worth something!
@GEMS@ +1
@MORE@
@GOTO@ @#ENDL

@#ENDL
@USER1@ =1
@GOTO@ @#MAINMENU

@##D
@IF@ USER2=0 @GOTO@ @#BEGIND
`%You'd rather not drink more than you need too...

@MORE@
@GOTO@ @#MAINMENU

@#BEGIND
@RANDOM@ 2
@##1
`%You take a big gulp of the bubbling liquid.  Tastes strange...

`%All of the sudden, you feel like you're on fire!  You fall over,
`%and don't get back up...
@VARIABLE1@ =HITPOINTS*1
@HITPOINTS@ =0

`0  You lose `#@*@VARIABLE1@*@ `%Hit-Points!  `!You just got `@killed!
`0  You now have `$@*@HITPOINTS@*@ `%Hit-Points.

@NEWS@
`#  @*@NAME@*@ `#disappeared into the `@Gateway Portal`@, but did not return...`@.
`%The poor fool drank hot lava, and got `@KILLED `%today!
@NEWSLINE@
@NEWSEND@   @;@ 08/06/07. added NewsEnd command line.
@KILL@

@##2
`%You take a small sip of the steaming liquid...

  `%You feel much stronger!!!
@VARIABLE1@ =STRENGTH%15
@STRENGTH@ +VARIABLE1

@USER2@ =1
@MORE@
@GOTO@ @#MAINMENU

@##J
@IF@ USER3=0 @GOTO@ @#BEGINJ
`%You don't need a bath right now.

@MORE@
@GOTO@ @#MAINMENU

@#BEGINJ
@RANDOM@ 2
@##1
`%You take a big leap into the Pool...
`%And immediately jump back out!  Damn that's hot!

`%You're burnt all over!
@VARIABLE1@ =HITPOINTS-1
    `#You just lost `$@*@VARIABLE1@*@ `%Hit-Points!
@HITPOINTS@ =1
@MORE@
@GOTO@ @#ENDJ

@##2
`%You wade in.  Feels nice...  in fact, it completely
`$HEALS `%your wounds!

@HEAL@
@MORE@
@GOTO@ @#ENDJ

@#ENDJ
@USER3@ =1
@GOTO@ @#MAINMENU

@#EXIT

`#You re-enter the `@Gateway Portal `#and are transported
`#back to your own time...

@END@

@;@  06-04-2003.  Revised menu key codes to be more visible.
@;@  07-01-2003.  Added support for Q to quit script.
@;@  July 2003:   Dark colors used according to Jason's preferences.
@;@  11/07/2003.  Placed version number on ScriptVersion line.
@;@  12/08/2004: Added RHP_Name coding to top line.

@;@ 08/06/07: v1.14. Added missing NEWSEND command line.
@;@ 08/06/07: Added "The poor fool ..." line.

@;@ 02/19/09 v1.16. Added SHOW command to start of script.
@;@     Script tested using new RHPTEST2.EXE utility.
@;@     Fixed problems with STRENGTH, GOLD, and KILL codes usage.
@;@ 02/23/09: fixed some coding errors.

@;@ 11/02/09: Rewrote during testing of GW13MAIN.exe v1.31 Beta.
@;@    Script changed to v1.20.
@;@ 11/10/09: fixed math coding errors in several statements.

@;@ 11/21/09: minor edits to some USER statements.