@;@Zycho Zircus v1.2
@;@Written by Dave Barton
@;@Internet: davedpf@verizon.net
@;@@PROGRAM@ GATEWAY
@;@@VERSION@ 1.0
@;@@NAME@ Zycho Zircus
@;@@LIMIT@ 1

@IF@ LIMIT>1 @GOTO@ @#Done
`%You're in the Zycho Zircus!  Welcome to the show!!
`0Zycho Zircus v1.2 by Dave Barton
`%
`%
`%
`%You head away from town & hear music...rock & roll music!
`%The music seems to be coming from a big top in the distance.  
`%Continue on?`l
@YESNO@
@##N
`@You decide that maybe the adventuring life isn't for you.
@GOTO@ @#Ending
@#Ending
@RANDOM@ 30
@##1
@##2
@##3
@##4
@##5
@##6
@##7
@##8
@##9
@##10
@##11
@##12
@##13
@##14
@##15
@##16
@##17
@##18
@##19
@##20
@##21
@##22
@##23
@##24
@##25
@##26
@##27
@##28
@##29
`%You leave the Zircus & head back to town.
@END@
@##30
@MORE@
@CLEAR@
`%As you begin to leave the Zircus, you spot a small child who seems lost.
`%As you approach, the child asks to go home with you!
@KIDS@ +1
@END@
@##Y
`%You always did love the Zircus, so you continue on...
@MORE@
@CLEAR@

`%As you approach, you see that there's a live band playing at the bandstand!
`%Across from them is the big top.  You realize the day is growing longer & you
`%only have time for one or the other...you can check out the band & see if they
`%have time to talk to you between songs, or (being the big strong adventurer
`%that you are) you can head over to the big top & look for work.
@MORE@
`%TIP: This is a `!low risk = low reward `%vs `$high risk = high reward `%IGM.
`%There is a chance of failure with either option.
`%One is `!less risky `%& provides a `!lower reward `%IF successful.
`%The other is `$higher risk `%& likewise provides a `$higher reward `%IF successful.
@MORE@
`%So what's your decision today?

`%(`!I`%) `!I'm a groupie at heart, I wanna see the band!
`%(`$S`%) `$Screw the band, I'm looking for work!
`%(`6M`%) `6Mommy, I'm scared!  Take me home!!
@PROMPT@ ISM
@##M
`@You got a fear of clowns or something?  Ok, you asked for it...
@MORE@
@CLEAR@
`%You run back to town, screaming like a frightened school girl!
`%Now everybody in town thinks you're a wuss!
@CHARM@ -5
@END@
@##I
@CLEAR@
@RANDOM@ 5
@##1
`%You wait & wait & wait for the band to break between songs,
`%but they just keep playing.  Its getting late, so you decide to
`%leave.  Maybe you can catch them tomorrow.
@MORE@
@GOTO@ @#Ending
@##2
@##3
@##4
@##5
`%You approach the band just as they finish a song.  You can't help but notice
`%how different each one of them is from the rest.  Looking at them, you
`%determine one of them is a `@Devil`%, one is a `#Lover`%, another is a `0Feline`%,
`%and the last is an `9Alien`%.  These four seem kinda familiar to you when you
`%think about it, like they've been coming to town for at least the last 35 years!
@MORE@
`%Although 2 of them do look just a little different from what you remember
`%when you were a child...
@MORE@
`%The four beings look at you expectantly.
`%Which of them do you wish to speak with?

`%(`@D`%) `@Devil
`%(`#L`%) `#Lover
`%(`0F`%) `0Feline
`%(`9A`%) `9Alien
@PROMPT@ DLFA
@##D
@CLEAR@
`@You approach the Devil & he speaks of war & death.
`@From this, you are inspired to go out & slay your enemy!
@FIGHTS@ +1
@GOTO@ @#Ending
@##L
@CLEAR@
`%You approach the Lover & he speaks of what the opposite sex wants in a mate.
`%From this, you feel more confident in relationships!
@CHARM@ +1
@GOTO@ @#Ending
@##F
@CLEAR@
`0You approach the Feline & he speaks of prowling through the jungle.
`0From this, you are inspired to make one more trip through the forest!
@FOREST@ +1
@GOTO@ @#Ending
@##A
@CLEAR@
`9You approach the Alien & he speaks of his home planet being
`9made entirely of gems.  As you are ready to leave he offers you
`9a gem, stating its of no value to him!
@GEMS@ +1
@GOTO@ @#Ending
@##S
@CLEAR@
`%You approach the Big Top & ask to speak to the Ringmaster about work.
`%You are directed around back where you easily find him and ask "Could you
`%use another act?"
@MORE@
`%The Ringmaster smiles and says "Well, we've got 3 spots open, actually.
`%You'll get paid whether you succeed or not, but they're all equally risky.
`%We could use a `6liontamer, `4human cannonball, `%and a `3tightrope walker.
@MORE@
`%Which act would you like to perform?"

`%(`6L`%) `6I can tame a lion, bring him on!
`%(`4C`%) `4I've always wanted to get shot out of a cannon!
`%(`3T`%) `3I'm not afraid of heights, I'll walk the tightrope!
@PROMPT@ LCT
@##L
@CLEAR@
`%You enter the lion's cage armed with nothing but a whip.
@MORE@
`%You crack the whip at the lion, just like you've always seen it done!
@MORE@
@RANDOM@ 4
@##1
@##2
@##3
`%Or, at least you TRY to...you must be doing something wrong!
@MORE@
`%Things don't go as smoothly as you'd planned,
`%as the lion lunges towards you & mauls you nearly to death!
@MORE@
@HITPOINTS@ =1
`@Your Hit Points go down, WAY down!
@MORE@
`%The Ringmaster meets you at the cage door,
`%as you barely escape with your life.
@GOTO@ @#Fail
@##4
`%Hey, this is working!  For the next ten minutes, you crack
`%your whip at the lion with expert precision & make him
`%do exactly what you want him to!
@MORE@
`%From "attacking" so well with your whip, your aim has become truer!
@STRENGTH@ +LEVEL*10
@MORE@
`%Oh, and the Ringmaster pays you as well...
@GOLD@ +500
@GOTO@ @#Ending
@##C
@CLEAR@
`%You strap on a leather helmet & climb inside a giant cannon.
`%The crowd counts down from 10 to 1 as you anxiously wait.
@MORE@
`@----====KABOOM!!!====----
@MORE@
`%You sail 300 feet through the air & manage to land...
@MORE@
@RANDOM@ 4
@##1
@##2
@##3
`%right on your head!  `@Your Hit Points go down, WAY down!
@HITPOINTS@ =1
@MORE@
`%The Ringmaster comes over & looks down at you, shaking his
`%head sadly.  "I didn't know the human neck could bend that way!"
@GOTO@ @#Fail
@##4
`%safely!  You tucked & rolled perfectly, minimizing the impact!
`%The crowd goes wild as you stand up & take a bow!
@MORE@
`%For taking such a huge fall without hurting yourself,
`%you learned the secret of how to take more damage!
@HITPOINTS@ +LEVEL*10
@MORE@
`%Oh, and the Ringmaster pays you as well...
@GOLD@ +500
@GOTO@ @#Ending
@##T
@CLEAR@
`%You climb a pole to get to the tightrope.  Jeez, its high!
`%You step out onto the thin wire & do your best not to look down...
@MORE@
@RANDOM@ 4
@##1
@##2
@##3
`%but curiosity gets the best of you!  You glance down for just a
`%moment & lose your balance immediately!
@MORE@
`%You fall like a 2-ton heavy thing & land in a crumpled heap!
`@Your Hit Points go down, WAY down!
@HITPOINTS@ =1
@MORE@
`%The Ringmaster comes over & looks down at you, shaking his
`%head sadly.  "I didn't know the human body could bend that way!"
@GOTO@ @#Fail
@##4
`%and you cautiously manage to inch across to the other side!
@MORE@
`%For using your balance to cross the tightrope,
`%you learn to better anticipate which way to shift your weight!
`%You realize how handy this could be when dodging a weapon!
@DEFENSE@ +LEVEL*10
@MORE@
`%Oh, and the Ringmaster pays you as well...
@GOLD@ +500
@GOTO@ @#Ending
@#Fail
@MORE@
`%"Sorry, kid.  I warned you it was risky," he tells you.
`%"But here's your pay, exactly as promised."
@GOLD@ +500
@GOTO@ @#Ending
@#Done
`%Sorry, you were told you only had time for one visit today.
`%The Zircus has already closed up & bedded down for the night.
`%You can come back again tomorrow.
@END@